#!/usr/bin/perl
# Author: Alan J. Pippin
# Description: Take a list of video files and create a single mkv video file from them

# Pre-requisites:
# mkvtoolnix - http://www.bunkus.org/videotools/mkvtoolnix/
# ffmpeg

####################################################################################################
# Includes
use File::Copy;
use File::Basename;
use Getopt::Std;
use File::stat;
use DateTime;
use DateTime::Duration;
use DateTime::Format::Duration;

####################################################################################################
# Configuration parameters - CHANGE THESE TO SUITE YOUR NEEDS
my $mkvmerge='mkvmerge';
my $ffmpeg='ffmpeg';
my $handbrake='HandBrakeCLI';
my $tmpfile = `tempfile`; chomp($tmpfile);
my $chapter_file = $tmpfile;
my $input_file_options = "-S";
my $output_file_options = "--chapters $chapter_file --compression -1:none";
my $timezone = `cat /etc/timezone`; chomp($timezone);
my $interlaced_requantize_quality=0.85;
my $progressive_requantize_quality=0.7;
####################################################################################################


####################################################################################################
# Command Line Options
getopts("sqt:o:i:h");

if(! defined $opt_t) { &usage(); die "-E- Missing required title: -t <title>\n"; }
if(! defined $opt_o) { &usage(); die "-E- Missing required argument output video names: -o <output.mkv>\n"; }
if(! defined $opt_i) { &usage(); die "-E- Missing required argument input video names: -i <input,input,...>\n"; }

sub usage {
    print "usage: $0 -t <title> -o <output.mkv> -i <input,input,...>\n";
    print "  -t <title>            Sets the general title for the output video file\n";
    print "  -o <output.mkv>       Sets the name of the output mkv file\n";
    print "  -i <input,input,...>  Sets the name of the input files to make into an mkv file\n";
    print "  -q                    Requantize MTS input videos to decrease output video size (requires HandBrakeCLI)\n";
    print "  -s                    Simulate mode. Don't actually make the video, but tell us what you will do\n";
    print "\n";
    return 1;
}

####################################################################################################
# Helper Subroutines
sub epoch_to_date {
    my ($epoch) = @_;
    my $mtime = DateTime->from_epoch(epoch => $epoch);
    $mtime->set_time_zone($timezone);
    return sprintf("%4d",$mtime->year)."-".sprintf("%02d",$mtime->month)."-".sprintf("%02d",$mtime->day)." ".$mtime->hms;
}

####################################################################################################
# MAIN

# Turn the list of input videos into a hash with a value equal to the modification time in epoch seconds
my %videos;
foreach $video (split(/,/, $opt_i)) {
    if(! -r "$video") { die "-E- Unable to read input video file: $video\n"; }
    my $mtime_epoch = stat("$video")->mtime;
    my $mdate = epoch_to_date($mtime_epoch);
    $videos{$video} = $mtime_epoch;
}

# Create the chapters file for the mkv file.
# Make each video file it's own chapter in the MKV file.
# Name the chapter with the date and time the video clip was taken (modified date).
print "-> Creating $opt_o with title '$opt_t' from the following video files in last modified date order:\n";
open(CHAPTERS,">$chapter_file") || die "-E- Unable to create chapter file: $chapter_file\n";
my $chapter_num = 0;
my $chapter_timecode = DateTime::Duration->new(years => 2000, hours => 0, minutes => 0, seconds => 0);
my $timecode_format = DateTime::Format::Duration->new(pattern => '%H:%M:%S.%3N', normalize => 1);
foreach my $video (sort{$videos{$a} <=> $videos{$b}} keys %videos) {
    $chapter_num++;
    my $hour = 0;
    my $min  = 5;
    my $sec  = 0;
    my $mtime_epoch = stat("$video")->mtime;
    my $mdate = epoch_to_date($mtime_epoch);
    my $duration = `$ffmpeg -i "$video" 2>&1 | grep Duration`;
    if($duration =~ /Duration: (\d+):(\d+):(\d+)\.(\d+)/) {
	$hour = $1;
	$min = $2;
	$sec = "$3.$4";
    }
    my $timecode = $timecode_format->format_duration($chapter_timecode);
    print "$mdate $hour:$min:$sec  -> $video \n";
    print CHAPTERS "CHAPTER".sprintf("%02d",$chapter_num)."=".$timecode."\n";
    print CHAPTERS "CHAPTER".sprintf("%02d",$chapter_num)."NAME=".$mdate."\n";
    my $dt = DateTime::Duration->new(years => 2000, hours => $hour, minutes => $min, seconds => $sec);
    $chapter_timecode = $chapter_timecode + $dt;
}
close(CHAPTERS);
print "\n-> Creating the following chapter file for this video:\n";
$chapter_file_contents = `cat $chapter_file`;
print "$chapter_file_contents\n";

# Create the mkv video
print "-> Creating the MKV video file '$opt_o'\n";

my $cmd = "$mkvmerge --title \"$opt_t\" $output_file_options -o \"$opt_o\"";

# Make our input file command line options for all the videos
my $video_count = 0;
my @video_tmp_files;
foreach my $video (sort{$videos{$a} <=> $videos{$b}} keys %videos) {
    # Make a note of the video extension
    my $video_ext = $video;
    $video_ext =~ s/.*\.(\S+)$/$1/;

    # Detect if the input file is interlaced or not.
    # There is a bug in mkvmerge 5.0.1 and earlier where if the video content is 1080i, it doesn't mux it properly, and it stutters.
    # The quick solution to this issue is to run the interlaced video file through ffmpeg and tell it to copy the video/audio streams to a mkv container.
    # We will then merge this temporarily created mkv container into the final mkv container instead of the original interlaced video.
    # http://ubuntuforums.org/showthread.php?t=1627194
    # http://forum.doom9.org/showthread.php?t=155732&page=31
    my $progressive = system('$ffmpeg -i "$video" 2>&1 | grep -q "frame rate differs"');
    if(!$progressive) {
	my $video_mkv = $video;
	print "   Detected interlaced video content: $video\n";
	if($video_ext !~ /mkv/i) {
	    $video_mkv =~ s/\.[^.]*$//; $video_mkv .= ".ffmpeg.mkv";
	    print "   Re-muxing the interlaced video content as an mkv file: $video_mkv\n";
	    my $make_mkv_cmd = "$ffmpeg -y -i \"$video\" -scodec copy -acodec copy -vcodec copy -f matroska \"$video_mkv\" > /dev/null 2>&1";
	    if(! defined $opt_s) { 
		my $errno = system("$make_mkv_cmd");
		$errno = $errno >> 8;
		if($errno > 1) {
		    unlink "$video_mkv";
		    die "-E- ffmpeg encountered some errors with exit code $errno\n";
		}
	    }
	    # Push the name of our intermediate video file onto a list of files to delete on exit
	    push(@video_tmp_files, "$video_mkv");
	    # Update the name of our video file to equal the name of our new intermediate video file name
	    $video = $video_mkv;
	}
    } else { 
	print "   Detected progressive video content: $video\n";
    }

    # Re-quantize the input video to reduce the resulting output filesize
    # This also gives us a chance to deinterlace the video as well
    # Only do this for .MTS videos
    if((defined $opt_q) && ($video_ext =~ /mts/i)) {

	# Set our requantize factor accordingly
	my $requantize_option = "";
	if(!$progressive) { $requantize_option = "-q $interlaced_requantize_quality"; }
	else { $requantize_option = "-q $progressive_requantize_quality"; }
	
	# Set our de-interlace option accordingly
	my $deinterlace_option = "";
	if(!$progressive) { $deinterlace_option = "-d"; }

	# Use HandBrake to requantize/deinterlace the input video
	my $video_mp4 = $video; $video_mp4 =~ s/\.[^.]*$//; $video_mp4 .= ".hb.mp4";
	print "   Re-quantizing input video content: $video_mp4\n";
	my $handbrake_cmd = "$handbrake $deinterlace_option $requantize_option -E ac3 -i \"$video\" -o \"$video_mp4\" > /dev/null 2>&1";
	if(! defined $opt_s) { 
	    my $errno = system("$handbrake_cmd");
	    $errno = $errno >> 8;
	    if($errno > 1) {
		unlink "$video_mp4";
		die "-E- handbrake encountered some errors with exit code $errno\n";
	    }
	}
	
	# Push the name of our intermediate video file onto a list of files to delete on exit
	push(@video_tmp_files, "$video_mp4");
	# Update the name of our video file to equal the name of our new intermediate video file name
	$video = $video_mp4;
    }
    
    # Create our input file command line options for this video
    if($video_count == 0) {
	$cmd .= " $input_file_options \"$video\"";
    } else {
	$cmd .= " $input_file_options + \"$video\"";
    }
    $video_count++;
}

# Execute our command line
print "\n$cmd\n";
if(! defined $opt_s) { 
    my $errno = system("$cmd");
    $errno = $errno >> 8;
    if($errno > 1) {
	unlink "$opt_o";
	die "-E- mkvmerge encountered some errors with exit code $errno\n";
    }
}

# Remove the temporary file used for the chapter generation
if(-e "$tmpfile") { unlink "$tmpfile"; }

# Remove any temporary video files created during the merge process
foreach my $video (@video_tmp_files) {
    if(-e "$video") { unlink "$video"; }
}

####################################################################################################